[PATCH (draft) 1/2] emacs: allow the user to toggle the visibility of multipart/alternative parts

[Mark Walters]

This patch adds a keybinding to the buttons in the notmuch-show emacs
buffer to allow the user to toggle the visibility of each part of a
message in the show buffer.  This is particularly useful for
multipart/alternative parts where the parts are not really
alternatives but contain different information.
---
 emacs/notmuch-show.el |   47 +++++++++++++++++++++++++++++++++++++++--------
 1 files changed, 39 insertions(+), 8 deletions(-)

diff --git a/emacs/notmuch-show.el b/emacs/notmuch-show.el
index 0f54259..9157669 100644
--- a/emacs/notmuch-show.el
+++ b/emacs/notmuch-show.el
@@ -155,6 +155,10 @@ indentation."
 (make-variable-buffer-local 'notmuch-show-indent-content)
 (put 'notmuch-show-indent-content 'permanent-local t)
 
+(defvar notmuch-show-message-multipart/alternative-display-parts nil)
+(make-variable-buffer-local 'notmuch-show-message-multipart/alternative-display-parts)
+(put 'notmuch-show-message-multipart/alternative-display-parts 'permanent-local t)
+
 (defcustom notmuch-show-stash-mlarchive-link-alist
   '(("Gmane" . "http://mid.gmane.org/")
     ("MARC" . "http://marc.info/?i=")
@@ -455,6 +459,7 @@ message at DEPTH in the current thread."
     (define-key map "v" 'notmuch-show-part-button-view)
     (define-key map "o" 'notmuch-show-part-button-interactively-view)
     (define-key map "|" 'notmuch-show-part-button-pipe)
+    (define-key map "t" 'notmuch-show-part-button-internally-show)
     map)
   "Submap for button commands")
 (fset 'notmuch-show-part-button-map notmuch-show-part-button-map)
@@ -531,6 +536,16 @@ message at DEPTH in the current thread."
     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
       (mm-pipe-part handle))))
 
+(defun notmuch-show-internally-show-part (message-id nth &optional filename content-type)
+  "Set a part to be displayed internally"
+  (let ((current-parts (lax-plist-get notmuch-show-message-multipart/alternative-display-parts message-id)))
+    (setq notmuch-show-message-multipart/alternative-display-parts
+	  (lax-plist-put notmuch-show-message-multipart/alternative-display-parts message-id
+			 (if (memq nth current-parts)
+			     (delq nth current-parts)
+			   (cons nth current-parts)))))
+  (notmuch-show-refresh-view))
+
 (defun notmuch-show-multipart/*-to-list (part)
   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 	  (plist-get part :content)))
@@ -543,12 +558,15 @@ message at DEPTH in the current thread."
     ;; This inserts all parts of the chosen type rather than just one,
     ;; but it's not clear that this is the wrong thing to do - which
     ;; should be chosen if there are more than one that match?
+
+    ;; The variable user-parts says which parts should override the
+    ;; default so we use xor (handcoded since lisp does not have it).
+
     (mapc (lambda (inner-part)
 	    (let ((inner-type (plist-get inner-part :content-type)))
-	      (if (or notmuch-show-all-multipart/alternative-parts
-		      (string= chosen-type inner-type))
-		  (notmuch-show-insert-bodypart msg inner-part depth)
-		(notmuch-show-insert-part-header (plist-get inner-part :id) inner-type inner-type nil " (not shown)"))))
+	      (notmuch-show-insert-bodypart msg inner-part depth
+					    (not (or notmuch-show-all-multipart/alternative-parts
+						     (string= chosen-type inner-type))))))
 	  inner-parts)
 
     (when notmuch-show-indent-multipart
@@ -806,11 +824,20 @@ message at DEPTH in the current thread."
       (setq handlers (cdr handlers))))
   t)
 
-(defun notmuch-show-insert-bodypart (msg part depth)
-  "Insert the body part PART at depth DEPTH in the current thread."
-  (let ((content-type (downcase (plist-get part :content-type)))
+(defun notmuch-show-insert-bodypart (msg part depth &optional not-shown)
+  "Insert the body part PART at depth DEPTH in the current thread.
+
+If not-shown is TRUE then do not show the part unless the user
+has overridden the default for this part"
+  (let ((user-parts (lax-plist-get notmuch-show-message-multipart/alternative-display-parts
+				   (notmuch-id-to-query (plist-get msg :id))))
+	(content-type (downcase (plist-get part :content-type)))
 	(nth (plist-get part :id)))
-    (notmuch-show-insert-bodypart-internal msg part content-type nth depth content-type))
+    (when (memq nth user-parts)
+      (setq not-shown (not not-shown)))
+    (if not-shown
+	(notmuch-show-insert-part-header nth content-type content-type nil " (not shown)")
+      (notmuch-show-insert-bodypart-internal msg part content-type nth depth content-type)))
   ;; Some of the body part handlers leave point somewhere up in the
   ;; part, so we make sure that we're down at the end.
   (goto-char (point-max))
@@ -1895,6 +1922,10 @@ the user (see `notmuch-show-stash-mlarchive-link-alist')."
   (interactive)
   (notmuch-show-part-button-internal button #'notmuch-show-pipe-part))
 
+(defun notmuch-show-part-button-internally-show (&optional button)
+  (interactive)
+  (notmuch-show-part-button-internal button #'notmuch-show-internally-show-part))
+
 (defun notmuch-show-part-button-internal (button handler)
   (let ((button (or button (button-at (point)))))
     (if button
-- 
1.7.9.1