[PATCH 1/2] emacs: User-defined sections in notmuch-hello
Daniel Schoepe
daniel.schoepe at googlemail.com
Wed Jun 29 13:27:00 PDT 2011
This patch makes the notmuch-hello screen fully customizable
by allowing the user to add and remove arbitrary sections. It
also provides some convenience functions for constructing sections,
e.g. showing the unread message count for each tag.
This is done by specifying a list of functions that will be run
when notmuch-hello is invoked.
---
emacs/notmuch-hello.el | 553 +++++++++++++++++++++++++++++-------------------
1 files changed, 339 insertions(+), 214 deletions(-)
diff --git a/emacs/notmuch-hello.el b/emacs/notmuch-hello.el
index 65fde75..e4c9307 100644
--- a/emacs/notmuch-hello.el
+++ b/emacs/notmuch-hello.el
@@ -55,26 +55,6 @@
:type 'boolean
:group 'notmuch)
-(defcustom notmuch-hello-tag-list-make-query nil
- "Function or string to generate queries for the all tags list.
-
-This variable controls which query results are shown for each tag
-in the \"all tags\" list. If nil, it will use all messages with
-that tag. If this is set to a string, it is used as a filter for
-messages having that tag (equivalent to \"tag:TAG and (THIS-VARIABLE)\").
-Finally this can be a function that will be called for each tag and
-should return a filter for that tag, or nil to hide the tag."
- :type '(choice (const :tag "All messages" nil)
- (const :tag "Unread messages" "tag:unread")
- (const :tag "Custom filter" string)
- (const :tag "Custom filter function" function))
- :group 'notmuch)
-
-(defcustom notmuch-hello-hide-tags nil
- "List of tags to be hidden in the \"all tags\"-section."
- :type '(repeat string)
- :group 'notmuch)
-
(defface notmuch-hello-logo-background
'((((class color)
(background dark))
@@ -123,6 +103,58 @@ Typically \",\" in the US and UK and \".\" in Europe."
(defvar notmuch-hello-recent-searches nil)
+(define-widget 'notmuch-hello-customized-section 'lazy
+ "Customize-type for notmuch-hello sections."
+ :tag "Customized section"
+ :type
+ (let ((opts
+ '((:title (string :tag "Title for this section"))
+ (:make-query (string :tag "Filter for each tag"))
+ (:make-count (string :tag "Different query to generate counts"))
+ (:hide-tags (repeat :tag "Tags that will be hidden" string))
+ (:initially-hidden (boolean :tag "Hide this on startup?"))
+ (:hide-empty-tags (boolean :tag "Hide tags with no matching messages"))
+ (:hide-if-empty (boolean :tag "Hide if empty")))))
+ `(list :tag "" (const :tag "" lambda) (const :tag "" nil)
+ (list :tag "Options"
+ (const :tag "" apply)
+ (const :tag "" (quote notmuch-hello-insert-all-tags))
+ (list :tag "" (const :tag "" quote)
+ (plist :options ,opts))))))
+
+(defcustom notmuch-hello-sections
+ (list #'notmuch-hello-insert-header
+ #'notmuch-hello-insert-saved-searches
+ #'notmuch-hello-insert-search
+ #'notmuch-hello-insert-recent-searches
+ #'notmuch-hello-insert-alltags
+ #'notmuch-hello-insert-footer)
+ "Sections for notmuch-hello.
+
+Each entry of this list should be a function of no arguments
+that should return if notmuch-hello-target is produced as part
+of its output and nil otherwise. The functions will be run
+to construct the content of the notmuch-hello buffer
+in the order they appear in this list."
+ :group 'notmuch
+ :type
+ '(repeat
+ (choice (function-item notmuch-hello-insert-header)
+ (function-item notmuch-hello-insert-saved-searches)
+ (function-item notmuch-hello-insert-search)
+ (function-item notmuch-hello-insert-recent-searches)
+ (function-item notmuch-hello-insert-alltags)
+ (function-item notmuch-hello-insert-footer)
+ notmuch-hello-customized-section)))
+
+;; only defined to avoid compilation warnings about free variables
+(defvar notmuch-hello-target nil)
+
+(defvar notmuch-hello-hidden-sections nil
+ "List of query sections whose contents are hidden")
+
+(defvar notmuch-hello-first-run t)
+
(defun notmuch-hello-remember-search (search)
(if (not (member search notmuch-hello-recent-searches))
(push search notmuch-hello-recent-searches))
@@ -238,12 +270,40 @@ should be. Returns a cons cell `(tags-per-line width)'."
(* tags-per-line (+ 9 1))))
tags-per-line))))
-(defun notmuch-hello-insert-tags (tag-alist widest target)
- (let* ((tags-and-width (notmuch-hello-tags-per-line widest))
+(defun notmuch-hello-query-entries (tag-alist &optional hide-empty)
+ "Compute list of counts and queries for TAG-ALIST.
+
+If HIDE-EMPTY is non-nil, entries with no matching messages will be
+removed from the result."
+ (notmuch-remove-if-not
+ #'identity
+ (mapcar
+ (lambda (elem)
+ (let* ((name (car elem))
+ (query-and-count (if (consp (cdr elem))
+ ;; do we have a different query for the message count?
+ (cons (second elem) (third elem))
+ (cons (cdr elem) (cdr elem))))
+ (message-count
+ (string-to-number (notmuch-saved-search-count
+ (cdr query-and-count)))))
+ (and (or (not hide-empty) (> message-count 0))
+ (list name (car query-and-count) message-count))))
+ tag-alist)))
+
+(defun notmuch-hello-insert-tags (entries)
+ "Insert query items from ENTRIES.
+
+ENTRIES must be a list containing lists of the form (NAME QUERY COUNT), where
+QUERY is the query to start when the button for the corresponding entry is
+activated. COUNT should be the number of messages matching the query.
+Such a list can be computed with `notmuch-hello-query-entries'."
+ (let* ((widest (notmuch-hello-longest-label entries))
+ (tags-and-width (notmuch-hello-tags-per-line widest))
(tags-per-line (car tags-and-width))
(widest (cdr tags-and-width))
(count 0)
- (reordered-list (notmuch-hello-reflect tag-alist tags-per-line))
+ (reordered-list (notmuch-hello-reflect entries tags-per-line))
;; Hack the display of the buttons used.
(widget-push-button-prefix "")
(widget-push-button-suffix "")
@@ -253,13 +313,13 @@ should be. Returns a cons cell `(tags-per-line width)'."
(mapc (lambda (elem)
;; (not elem) indicates an empty slot in the matrix.
(when elem
- (let* ((name (car elem))
- (query (cdr elem))
+ (let* ((name (first elem))
+ (query (second elem))
+ (count (third elem))
(formatted-name (format "%s " name)))
(widget-insert (format "%8s "
- (notmuch-hello-nice-number
- (string-to-number (notmuch-saved-search-count query)))))
- (if (string= formatted-name target)
+ (notmuch-hello-nice-number count)))
+ (if (string= formatted-name notmuch-hello-target)
(setq found-target-pos (point-marker)))
(widget-create 'push-button
:notify #'notmuch-hello-widget-search
@@ -277,7 +337,7 @@ should be. Returns a cons cell `(tags-per-line width)'."
(setq count (1+ count))
(if (eq (% count tags-per-line) 0)
(widget-insert "\n")))
- reordered-list)
+ entries)
;; If the last line was not full (and hence did not include a
;; carriage return), insert one now.
@@ -325,59 +385,266 @@ should be. Returns a cons cell `(tags-per-line width)'."
(fset 'notmuch-hello-mode-map notmuch-hello-mode-map)
(defun notmuch-hello-mode ()
- "Major mode for convenient notmuch navigation. This is your entry portal into notmuch.
+ "Major mode for convenient notmuch navigation. This is your entry portal into notmuch.
Complete list of currently available key bindings:
\\{notmuch-hello-mode-map}"
- (interactive)
- (kill-all-local-variables)
- (use-local-map notmuch-hello-mode-map)
- (setq major-mode 'notmuch-hello-mode
- mode-name "notmuch-hello")
- ;;(setq buffer-read-only t)
-)
-
-(defun notmuch-hello-generate-tag-alist ()
+ (interactive)
+ (kill-all-local-variables)
+ (use-local-map notmuch-hello-mode-map)
+ (setq major-mode 'notmuch-hello-mode
+ mode-name "notmuch-hello")
+ ;;(setq buffer-read-only t)
+ )
+
+(defun notmuch-hello-make-query (tag make-query)
+ (cond
+ ((functionp make-query)
+ (let ((result (funcall make-query tag)))
+ (and result (concat "tag:" tag " and (" result ")"))))
+ ((stringp make-query)
+ (concat "tag:" tag " and (" make-query ")"))
+ (t (concat "tag:" tag))))
+
+(defun notmuch-hello-generate-tag-alist (&optional hide-tags make-query make-count)
"Return an alist from tags to queries to display in the all-tags section."
(notmuch-remove-if-not
- #'cdr
+ #'identity
(mapcar (lambda (tag)
- (cons tag
- (cond
- ((functionp notmuch-hello-tag-list-make-query)
- (concat "tag:" tag " and ("
- (funcall notmuch-hello-tag-list-make-query tag) ")"))
- ((stringp notmuch-hello-tag-list-make-query)
- (concat "tag:" tag " and ("
- notmuch-hello-tag-list-make-query ")"))
- (t (concat "tag:" tag)))))
+ (let ((query (notmuch-hello-make-query tag make-query)))
+ (when query
+ (if make-count
+ (list tag (notmuch-hello-make-query tag make-query)
+ (notmuch-hello-make-query tag make-count))
+ (cons tag (notmuch-hello-make-query tag make-query))))))
(notmuch-remove-if-not
(lambda (tag)
- (not (member tag notmuch-hello-hide-tags)))
+ (not (member tag hide-tags)))
(process-lines notmuch-command "search-tags")))))
+(defun notmuch-hello-insert-header ()
+ "Insert the default notmuch-hello header."
+ (when notmuch-show-logo
+ (let ((image notmuch-hello-logo))
+ ;; The notmuch logo uses transparency. That can display poorly
+ ;; when inserting the image into an emacs buffer (black logo on
+ ;; a black background), so force the background colour of the
+ ;; image. We use a face to represent the colour so that
+ ;; `defface' can be used to declare the different possible
+ ;; colours, which depend on whether the frame has a light or
+ ;; dark background.
+ (setq image (cons 'image
+ (append (cdr image)
+ (list :background (face-background 'notmuch-hello-logo-background)))))
+ (insert-image image))
+ (widget-insert " "))
+
+ (widget-insert "Welcome to ")
+ ;; Hack the display of the links used.
+ (let ((widget-link-prefix "")
+ (widget-link-suffix ""))
+ (widget-create 'link
+ :notify (lambda (&rest ignore)
+ (browse-url notmuch-hello-url))
+ :help-echo "Visit the notmuch website."
+ "notmuch")
+ (widget-insert ". ")
+ (widget-insert "You have ")
+ (widget-create 'link
+ :notify (lambda (&rest ignore)
+ (notmuch-hello-update))
+ :help-echo "Refresh"
+ (notmuch-hello-nice-number
+ (string-to-number (car (process-lines notmuch-command "count")))))
+ (widget-insert " messages.")))
+
+
+(defun notmuch-hello-insert-saved-searches ()
+ "Insert the saved-searches section."
+ (let ((entries (notmuch-hello-query-entries
+ notmuch-saved-searches
+ (not notmuch-show-empty-saved-searches)))
+ found-target-pos final-target-pos)
+ (when entries
+ (widget-insert "\nSaved searches: ")
+ (widget-create 'push-button
+ :notify (lambda (&rest ignore)
+ (customize-variable 'notmuch-saved-searches))
+ "edit")
+ (widget-insert "\n\n")
+ (setq final-target-pos (point-marker))
+ (let ((start (point)))
+ (setq found-target-pos
+ (notmuch-hello-insert-tags entries))
+ (if found-target-pos
+ (setq final-target-pos found-target-pos))
+ (indent-rigidly start (point) notmuch-hello-indent)
+ final-target-pos))))
+
+(defun notmuch-hello-insert-search ()
+ "Insert a search widget."
+ (widget-insert "Search: ")
+ (setq notmuch-hello-search-bar-marker (point-marker))
+ (widget-create 'editable-field
+ ;; Leave some space at the start and end of the
+ ;; search boxes.
+ :size (max 8 (- (window-width) notmuch-hello-indent
+ (length "Search: ")))
+ :action (lambda (widget &rest ignore)
+ (notmuch-hello-search (widget-value widget)))))
+
+(defun notmuch-hello-insert-recent-searches ()
+ "Insert recent searches."
+ (when notmuch-hello-recent-searches
+ (widget-insert "\nRecent searches: ")
+ (widget-create 'push-button
+ :notify (lambda (&rest ignore)
+ (setq notmuch-hello-recent-searches nil)
+ (notmuch-hello-update))
+ "clear")
+ (widget-insert "\n\n")
+ (let ((start (point))
+ (nth 0))
+ (mapc '(lambda (search)
+ (let ((widget-symbol (intern (format "notmuch-hello-search-%d" nth))))
+ (set widget-symbol
+ (widget-create 'editable-field
+ ;; Don't let the search boxes be
+ ;; less than 8 characters wide.
+ :size (max 8
+ (- (window-width)
+ ;; Leave some space
+ ;; at the start and
+ ;; end of the
+ ;; boxes.
+ (* 2 notmuch-hello-indent)
+ ;; 1 for the space
+ ;; before the
+ ;; `[save]' button. 6
+ ;; for the `[save]'
+ ;; button.
+ 1 6))
+ :action (lambda (widget &rest ignore)
+ (notmuch-hello-search (widget-value widget)))
+ search))
+ (widget-insert " ")
+ (widget-create 'push-button
+ :notify (lambda (widget &rest ignore)
+ (notmuch-hello-add-saved-search widget))
+ :notmuch-saved-search-widget widget-symbol
+ "save"))
+ (widget-insert "\n")
+ (setq nth (1+ nth)))
+ notmuch-hello-recent-searches)
+ (indent-rigidly start (point) notmuch-hello-indent))))
+
+(defun notmuch-hello-insert-query-list (title query-alist &rest options)
+ "Insert a section with TITLE showing tags from QUERY-ALIST.
+
+Supports the following entries in OPTIONS as a plist:
+:initially-hidden - if non-nil, section will be hidden on startup
+:hide-empty-tags - hide entries with no matching messages
+:hide-if-empty - hide if no entries would be shown
+ (only makes sense with :hide-empty-tags)
+
+QUERY-ALIST must be a list containing elements of the form (NAME . QUERY)
+or (NAME QUERY COUNT-QUERY). If the latter form is used,
+COUNT-QUERY specifies an alternate query to be used to generate
+the count for the associated tag."
+ (widget-insert title)
+ (if (and notmuch-hello-first-run (plist-get options :initially-hidden))
+ (add-to-list 'notmuch-hello-hidden-sections title))
+ (let ((is-hidden (member title notmuch-hello-hidden-sections))
+ (start (point)))
+ (if is-hidden
+ (widget-create 'push-button
+ :notify `(lambda (widget &rest ignore)
+ (setq notmuch-hello-hidden-sections
+ (delete ,title notmuch-hello-hidden-sections))
+ (notmuch-hello-update))
+ "show")
+ (widget-create 'push-button
+ :notify `(lambda (widget &rest ignore)
+ (add-to-list 'notmuch-hello-hidden-sections
+ ,title)
+ (notmuch-hello-update))
+ "hide"))
+ (widget-insert "\n")
+ (let (target-pos
+ (entries (notmuch-hello-query-entries
+ query-alist (plist-get options :hide-empty-tags))))
+ (when (and (not is-hidden)
+ (or (not (plist-get options :hide-if-empty))
+ entries))
+ (widget-insert "\n")
+ (setq target-pos
+ (notmuch-hello-insert-tags entries))
+ (indent-rigidly start (point) notmuch-hello-indent)
+ target-pos))))
+
+(defun notmuch-hello-insert-tags-section (&rest options)
+ "Insert a section displaying all tags and message counts for each.
+
+Allowed options are those accepted by `notmuch-hello-insert-query-list' and the
+following:
+
+:title - Title for this section, defaults to \"All tags: \"
+:make-query - This can be a function that takes a tag as its argument and
+ returns a filter to be used for the query for that tag or nil to hide the
+ tag. This can also be a string that is used as a filter for messages with that tag.
+:make-count - Seperate query to generate the count that should be displayed for each
+ tag. Accepts the same values as :make-query
+:hide-tags - List of tags that should be excluded."
+ (apply 'notmuch-hello-insert-query-list
+ (or (plist-get options :title) "All tags: ")
+ (notmuch-hello-generate-tag-alist
+ (plist-get options :hide-tags)
+ (plist-get options :make-query)
+ (plist-get options :make-count))
+ options))
+
+(defun notmuch-hello-insert-alltags ()
+ "Insert a section displaying all tags and associated message counts"
+ (notmuch-hello-insert-tags-section :initially-hidden
+ (not notmuch-show-all-tags-list)))
+
+(defun notmuch-hello-insert-footer ()
+ "Insert the notmuch-hello footer."
+ (let ((start (point)))
+ (widget-insert "Type a search query and hit RET to view matching threads.\n")
+ (when notmuch-hello-recent-searches
+ (widget-insert "Hit RET to re-submit a previous search. Edit it first if you like.\n")
+ (widget-insert "Save recent searches with the `save' button.\n"))
+ (when notmuch-saved-searches
+ (widget-insert "Edit saved searches with the `edit' button.\n"))
+ (widget-insert "Hit RET or click on a saved search or tag name to view matching threads.\n")
+ (widget-insert "`=' refreshes this screen. `s' jumps to the search box. `q' to quit.\n")
+ (let ((fill-column (- (window-width) notmuch-hello-indent)))
+ (center-region start (point)))))
+
+
;;;###autoload
(defun notmuch-hello (&optional no-display)
"Run notmuch and display saved searches, known tags, etc."
(interactive)
- ; Jump through a hoop to get this value from the deprecated variable
- ; name (`notmuch-folders') or from the default value.
+ ; Jump through a hoop to get this value from the deprecated variable
+ ; name (`notmuch-folders') or from the default value.
(if (not notmuch-saved-searches)
- (setq notmuch-saved-searches (notmuch-saved-searches)))
+ (setq notmuch-saved-searches (notmuch-saved-searches)))
(if no-display
(set-buffer "*notmuch-hello*")
(switch-to-buffer "*notmuch-hello*"))
- (let ((target (if (widget-at)
- (widget-value (widget-at))
- (condition-case nil
- (progn
- (widget-forward 1)
- (widget-value (widget-at)))
- (error nil)))))
+ (let ((notmuch-hello-target (if (widget-at)
+ (widget-value (widget-at))
+ (condition-case nil
+ (progn
+ (widget-forward 1)
+ (widget-value (widget-at)))
+ (error nil)))))
(kill-all-local-variables)
(let ((inhibit-read-only t))
@@ -391,167 +658,25 @@ Complete list of currently available key bindings:
(mapc 'delete-overlay (car all))
(mapc 'delete-overlay (cdr all)))
- (when notmuch-show-logo
- (let ((image notmuch-hello-logo))
- ;; The notmuch logo uses transparency. That can display poorly
- ;; when inserting the image into an emacs buffer (black logo on
- ;; a black background), so force the background colour of the
- ;; image. We use a face to represent the colour so that
- ;; `defface' can be used to declare the different possible
- ;; colours, which depend on whether the frame has a light or
- ;; dark background.
- (setq image (cons 'image
- (append (cdr image)
- (list :background (face-background 'notmuch-hello-logo-background)))))
- (insert-image image))
- (widget-insert " "))
-
- (widget-insert "Welcome to ")
- ;; Hack the display of the links used.
- (let ((widget-link-prefix "")
- (widget-link-suffix ""))
- (widget-create 'link
- :notify (lambda (&rest ignore)
- (browse-url notmuch-hello-url))
- :help-echo "Visit the notmuch website."
- "notmuch")
- (widget-insert ". ")
- (widget-insert "You have ")
- (widget-create 'link
- :notify (lambda (&rest ignore)
- (notmuch-hello-update))
- :help-echo "Refresh"
- (notmuch-hello-nice-number
- (string-to-number (car (process-lines notmuch-command "count")))))
- (widget-insert " messages.\n"))
-
- (let ((found-target-pos nil)
- (final-target-pos nil))
- (let* ((saved-alist
- ;; Filter out empty saved searches if required.
- (if notmuch-show-empty-saved-searches
- notmuch-saved-searches
- (loop for elem in notmuch-saved-searches
- if (> (string-to-number (notmuch-saved-search-count (cdr elem))) 0)
- collect elem)))
- (saved-widest (notmuch-hello-longest-label saved-alist))
- (alltags-alist (if notmuch-show-all-tags-list (notmuch-hello-generate-tag-alist)))
- (alltags-widest (notmuch-hello-longest-label alltags-alist))
- (widest (max saved-widest alltags-widest)))
-
- (when saved-alist
- (widget-insert "\nSaved searches: ")
- (widget-create 'push-button
- :notify (lambda (&rest ignore)
- (customize-variable 'notmuch-saved-searches))
- "edit")
- (widget-insert "\n\n")
- (setq final-target-pos (point-marker))
- (let ((start (point)))
- (setq found-target-pos (notmuch-hello-insert-tags saved-alist widest target))
- (if found-target-pos
- (setq final-target-pos found-target-pos))
- (indent-rigidly start (point) notmuch-hello-indent)))
-
- (widget-insert "\nSearch: ")
- (setq notmuch-hello-search-bar-marker (point-marker))
- (widget-create 'editable-field
- ;; Leave some space at the start and end of the
- ;; search boxes.
- :size (max 8 (- (window-width) notmuch-hello-indent
- (length "Search: ")))
- :action (lambda (widget &rest ignore)
- (notmuch-hello-search (widget-value widget))))
- (widget-insert "\n")
-
- (when notmuch-hello-recent-searches
- (widget-insert "\nRecent searches: ")
- (widget-create 'push-button
- :notify (lambda (&rest ignore)
- (setq notmuch-hello-recent-searches nil)
- (notmuch-hello-update))
- "clear")
- (widget-insert "\n\n")
- (let ((start (point))
- (nth 0))
- (mapc '(lambda (search)
- (let ((widget-symbol (intern (format "notmuch-hello-search-%d" nth))))
- (set widget-symbol
- (widget-create 'editable-field
- ;; Don't let the search boxes be
- ;; less than 8 characters wide.
- :size (max 8
- (- (window-width)
- ;; Leave some space
- ;; at the start and
- ;; end of the
- ;; boxes.
- (* 2 notmuch-hello-indent)
- ;; 1 for the space
- ;; before the
- ;; `[save]' button. 6
- ;; for the `[save]'
- ;; button.
- 1 6))
- :action (lambda (widget &rest ignore)
- (notmuch-hello-search (widget-value widget)))
- search))
- (widget-insert " ")
- (widget-create 'push-button
- :notify (lambda (widget &rest ignore)
- (notmuch-hello-add-saved-search widget))
- :notmuch-saved-search-widget widget-symbol
- "save"))
- (widget-insert "\n")
- (setq nth (1+ nth)))
- notmuch-hello-recent-searches)
- (indent-rigidly start (point) notmuch-hello-indent)))
-
- (when alltags-alist
- (widget-insert "\nAll tags: ")
- (widget-create 'push-button
- :notify (lambda (widget &rest ignore)
- (setq notmuch-show-all-tags-list nil)
- (notmuch-hello-update))
- "hide")
- (widget-insert "\n\n")
- (let ((start (point)))
- (setq found-target-pos (notmuch-hello-insert-tags alltags-alist widest target))
- (if (not final-target-pos)
- (setq final-target-pos found-target-pos))
- (indent-rigidly start (point) notmuch-hello-indent)))
-
- (widget-insert "\n")
-
- (if (not notmuch-show-all-tags-list)
- (widget-create 'push-button
- :notify (lambda (widget &rest ignore)
- (setq notmuch-show-all-tags-list t)
- (notmuch-hello-update))
- "Show all tags")))
-
- (let ((start (point)))
- (widget-insert "\n\n")
- (widget-insert "Type a search query and hit RET to view matching threads.\n")
- (when notmuch-hello-recent-searches
- (widget-insert "Hit RET to re-submit a previous search. Edit it first if you like.\n")
- (widget-insert "Save recent searches with the `save' button.\n"))
- (when notmuch-saved-searches
- (widget-insert "Edit saved searches with the `edit' button.\n"))
- (widget-insert "Hit RET or click on a saved search or tag name to view matching threads.\n")
- (widget-insert "`=' refreshes this screen. `s' jumps to the search box. `q' to quit.\n")
- (let ((fill-column (- (window-width) notmuch-hello-indent)))
- (center-region start (point))))
+ (let (final-target-pos)
+ (mapc
+ (lambda (section-fun)
+ (let ((result (funcall section-fun)))
+ (if (and (not final-target-pos) (integer-or-marker-p result))
+ (setq final-target-pos result))
+ (widget-insert "\n")))
+ notmuch-hello-sections)
(widget-setup)
-
+
(when final-target-pos
(goto-char final-target-pos)
(unless (widget-at)
(widget-forward 1)))
-
+
(unless (widget-at)
- (notmuch-hello-goto-search)))))
+ (notmuch-hello-goto-search)))
+ (setq notmuch-hello-first-run nil)))
(defun notmuch-folder ()
"Deprecated function for invoking notmuch---calling `notmuch' is preferred now."
--
1.7.5.4
More information about the notmuch
mailing list